Sabtu, 19 Maret 2011

RUMUS Ms EXCEL LAPORAN KEUANGAN pada perusahaan jasa

Rumus Laporan Keuangan
Perusahaan Jasa
1. Ref
    Nama sheet : Ref
Terdiri atas    - Ref/ No. Akun
            - Nama Perkiraan
Define name akun perkiraan Ref
    - blok seluruh akun perkiraan (ref)
    - klik insert
    - klik define name
    - ktik nama nama grupnya
        Contoh ; - accref
klik OK/ enter

2. Jurnal Umum
    Terdiri atas    :    - Nama Perusahaan
                - Jurnal Umum (Karena Jurnal Umum yang kita isi)
                - Periode Perusahaan
                   Misal        - 01 April 2000
- Halaman : JU 1     “karena Jurnal Umum”
- No
- Tanggal
- Nama Perkiraan
- Uraian
- Ref
- Debet
- Kredit
- Rumus  Nama Perkiraan :
=IF(OR(AND(F6<>"",G6=0,H6=0),AND(F6<>"",G6>0)),VLOOKUP(F6,accref,2),IF(AND(F6<>"",G6=0,H6>0),CONCATENATE(REPT(" ",8),VLOOKUP(F6,accref,2))," "))

- Di kolom Uraian ketik Jurnal Umum

3. Ayat Jurnal Penyesuaian & Ayat Jurnal Penutupan
    Nama sheet : AJP&Penutupan

    Terdiri atas    :    - Nama Perusahaan
- Ayat Jurnal Penyesuaian dan Ayat Jurnal Penutup
- Periode Perusahaan
- Halaman : JU    “karena AJP&Penutup”
- No
- Tanggal
- Nama Perkiraan
- Uraian
- Ref
- Debet
- Kredit

Membuat define name AJP
Define name ayat jurnal Penyesuaian& Ayat jurnal penutupan
Blok table ref s/d total kredit
Ketik nama grupnya
- contoh :    AJP

Membuat define name AJPDEBET
Define name ayat jurnal Penyesuaian& Ayat jurnal penutupan
Blok table ref s/d total kredit
Ketik nama grupnya
- contoh :    AJPDEBET

Membuat define name AJPKREDIT
Define name ayat jurnal Penyesuaian& Ayat jurnal penutupan
Blok table ref s/d total kredit
Ketik nama grupnya
- contoh :    AJPKREDIT

Nb :    Kegunaan define name     - AJP
                    - AJPDEBET
                    - AJPKREDIT
Untuk menghitung jumlah Penyesuaian di Neraca Lajur.

    - Rumus Nama Perkiraan
=IF(OR(AND(F6<>"",G6=0,H6=0),AND(F6<>"",G6>0)),VLOOKUP(F6,accref,2),IF(AND(F6<>"",G6=0,H6>0),CONCATENATE(REPT(" ",8),VLOOKUP(F6,accref,2))," "))
    - Di kolom Uraian ketik Penyesuaian

4. Posting ke Buku Besar Pembantu
    Kas
    Nama sheet pos(no perkiraan)

    Terdiri atas :         - Perkiraan
- Perkiraan No
    Misal : 101
- No baris
- Tanggal
- Uraian
- Ref
- Debet
- Kredit
- Saldo Debet
- Saldo Kredit
    - Rumus Tanggal
=IF('jurnal umum'!F6,'jurnal umum'!C6,"")
    - Rumus Nama Perkiraan
=IF(I2<>"",VLOOKUP(I2,accref,2),"")
- Rumus Uraian
=IF('jurnal umum'!F6=pos101!$I$2,'jurnal umum'!E6,"") > diganti menurut nomor perkiraan
    - Rumus Ref
=IF('jurnal umum'!F6=pos101!$I$2,'jurnal umum'!$H$4,"") > diganti menurut nomor perkiraan
- Rumus Debet
=IF('jurnal umum'!F6=pos101!$I$2,'jurnal umum'!G6,0) > diganti menurut nomor perkiraan
    - Rumus Kredit
=IF('jurnal umum'!F6=pos101!$I$2,'jurnal umum'!H6,0) > diganti menurut nomor perkiraan
    - Saldo Debet
(Saldo Awal)
=IF(OR(AND(LEFT($I$2,1)="1",NOT(RIGHT($I$2,1)="9")),$I$2=302,LEFT($I$2)="5"),F4-G4,0)
(Jumlah Saldo)
=IF(OR(AND(LEFT($I$2,1)="1",NOT(RIGHT($I$2,1)="9")),$I$2=302,LEFT($I$2,1)="5"),H4+F5-G5,0)
Saldo Kredit
(Saldo Awal)
=IF(OR($I$2=109,LEFT($I$2,1)="2",$I$2=301,LEFT($I$2,1)="4"),G4-F4,0)
(Jumlah Saldo)
=IF(OR($I$2=109,LEFT($I$2,1)="2",$I$2=301,LEFT($I$2,1)="4"),I4+G5-F5,0)

5. Neraca Percobaan
    Nama sheet : neraca percobaan
        Terdiri atas :    - Nama perusahaan
                - Neraca Percobaan “Karena neraca percobaan yang kita isi”
                - Periode
                    Misal : Per 30 April 2000
                - Nama Perkiraan
                - Ref
                - Debet
                - Kredit
- Rumus Nama Perkiraan
=VLOOKUP('neraca percobaan'!B6,accref,2,0)

- Rumus Debet
=pos101!H$51     > diganti menurut nomor perkiraan
- Rumus Kredit
=pos101!H$51    > diganti menurut nomor perkiraan

6. Neraca Lajur
    Nama sheet : neraca lajur
        Terdiri atas :    - Nomor
                    * urut
                    * Perkiraan
                - Nama Perkiraan
                - Neraca Percobaan
                    * Debet
                    * Kredit
                - Penyesuaian
                    * Debet
                    * Kredit
                - Neraca Saldo setelah Penyesuaian
                    * Debet
                    * Kredit
                - Rugi Laba
                    * Debet
                    * Kedit
                - Neraca
                    * Debet
                    * Kredit
Rumus No Perkiraan
=ref!A3
Rumus Nama Perkiraan
=ref!B3
Rumus Neraca Percobaan Debet
='neraca percobaan'!C6
Rumus Neraca Percobaan Kredit
='neraca percobaan'!D6
Rumus Penyesuaian Debet
=SUMIF(AJP,B7,AJPDEBET)
Rumus Penyesuaian Kredit
=SUMIF(AJP,B7,AJPKREDIT)
Rumus Neraca saldo setelah Penutupan Debet
=IF((D7+F7-G7)>0,(D7+F7-G7),0)
Rumus Neraca Saldo setelah Penutupan Kredit
=IF(AND(E7>0,D7=0),(E7+G7-F7),IF(AND(E7=0,D7=0),G7,0))
Rumus Rugi Laba Debet
=IF(OR(LEFT(B7,1)="4",LEFT(B7,1)="5"),H7,0)
Rumus Rugi Laba Kredit
=IF(OR(LEFT(B7,1)="4",LEFT(B7,1)="5"),I7,0)
Rumus Neraca Debet
=IF(OR(LEFT(B7,1)="1",LEFT(B7,1)="2",LEFT(B7,1)="3"),H7,0)
Rumus Neraca Kredit
=IF(OR(LEFT(B7,1)="1",LEFT(B7,1)="2",LEFT(B7,1)="3"),I7,0)